Benutzer-Werkzeuge

Webseiten-Werkzeuge


micro_pro_mini

Für besonders sparsame Sensoren eignet sich die Verwendung des Pro Mini Boards von Arduino. Diese sind günstig zu bekommen und können einfach mit 2 AA Batterien betrieben werden. Da mein gesamtes Wireless Netzwerk Nachrichten nur signiert verarbeitet, verwende ich auch bei den Pro Mini die Hardwareverschlüsselung unter Einsatz des ATSHA204 Chips von Atmel. Diese können einfach direkt auf den Pro Mini gelötet werden:

Für den Betrieb mit einem NRF24-Modul wird meistens der PIN 13 des Arduino zum Anschluss an den SCK-Pin des Funkmoduls verwendet. Dadurch leuchtet die verbaute LED des Moduls dauernd und ist für andere Aufgaben nicht mehr zu verwenden. Um dieses Problem zu umgehen, kann das Pin Assignment für das Funkmodul geändert werden. Dafür muss aber SOFT-SPI verwendet werden. Ein Beispiel Sketch sieht so aus:

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * REVISION HISTORY
 * Version 1.0 - Henrik Ekblad
 *
 * DESCRIPTION
 * Example sketch showing how to control physical relays.
 * This example will remember relay state after power failure.
 * http://www.mysensors.org/build/relay
 */
 
// Enable debug prints to serial monitor
#define MY_DEBUG
 
// SoftSPI verwenden um SCK an einem anderen PIN als 13 zu verwenden
// das vermeidet das die verbaute LED immer eingeschalten ist
#define MY_SOFTSPI
 
#ifndef MY_SOFT_SPI_SCK_PIN
#define MY_SOFT_SPI_SCK_PIN 8
#endif
 
/**
 * @def MY_SOFT_SPI_MISO_PIN
 * @brief Soft SPI MISO pin.
 */
#ifndef MY_SOFT_SPI_MISO_PIN
#define MY_SOFT_SPI_MISO_PIN 12
#endif
 
/**
 * @def MY_SOFT_SPI_MOSI_PIN
 * @brief Soft SPI MOSI pin.
 */
#ifndef MY_SOFT_SPI_MOSI_PIN
#define MY_SOFT_SPI_MOSI_PIN 11
#endif
 
// Enable and select radio type attached
#define MY_RADIO_NRF24
//#define MY_RADIO_RFM69
 
// Enable repeater functionality for this node
//#define MY_REPEATER_FEATURE
 
// Hardware Signieren aktivieren
#define MY_SIGNING_ATSHA204
#define MY_SIGNING_REQUEST_SIGNATURES
 
#include <SPI.h>
#include <MySensors.h>
 
#define RELAY_1  3  // Arduino Digital I/O pin number for first relay (second on pin+1 etc)
#define NUMBER_OF_RELAYS 1 // Total number of attached relays
#define RELAY_ON 1  // GPIO value to write to turn on attached relay
#define RELAY_OFF 0 // GPIO value to write to turn off attached relay
 
 
void before()
{
	for (int sensor=1, pin=RELAY_1; sensor<=NUMBER_OF_RELAYS; sensor++, pin++) {
		// Then set relay pins in output mode
		pinMode(pin, OUTPUT);
		// Set relay to last known state (using eeprom storage)
		digitalWrite(pin, loadState(sensor)?RELAY_ON:RELAY_OFF);
	}
}
 
void setup()
{
 
}
 
void presentation()
{
	// Send the sketch version information to the gateway and Controller
	sendSketchInfo("Relay", "1.0");
 
	for (int sensor=1, pin=RELAY_1; sensor<=NUMBER_OF_RELAYS; sensor++, pin++) {
		// Register all sensors to gw (they will be created as child devices)
		present(sensor, S_BINARY);
	}
}
 
 
void loop()
{
 
}
 
void receive(const MyMessage &message)
{
	// We only expect one type of message from controller. But we better check anyway.
	if (message.type==V_STATUS) {
		// Change relay state
		digitalWrite(message.sensor-1+RELAY_1, message.getBool()?RELAY_ON:RELAY_OFF);
		// Store state in eeprom
		saveState(message.sensor, message.getBool());
		// Write some debug info
		Serial.print("Incoming change for sensor:");
		Serial.print(message.sensor);
		Serial.print(", New status: ");
		Serial.println(message.getBool());
	}
}

Wichtig für das SoftSPI ist das includieren der benötigten Bibliothek: #include <SPI.h>

micro_pro_mini.txt · Zuletzt geändert: 2017/02/12 19:08 von admin